      SUBROUTINE FANERG ( KNIVAU )
#include "facom0.h"
C****
C        Ce sous-programme se charge de mettre le Niveau Global d'Erreur
C     Fatale du logiciel de Fichiers ARPEGE (*NRFAGA*) a la valeur
C     KNIVAU, de meme que la variable correspondante du logiciel LFI.
C     Par defaut, NRFAGA vaut 1.
C**
C        Argument : KNIVAU (Entree) ==> Niveau global d'erreur fatale.
C                                       Valeurs possibles:
C
C     0 : Rendre fatale toute erreur detectee, meme si elle correspond
C         a un fichier ouvert avec l'option "pas d'erreur fatale".
C     1 : Ne rend fatales que certaines erreurs "globales", c'est-a-dire
C         non reliables a un fichier ouvert, et les erreurs sur les fi-
C         chiers ouverts avec l'option "erreur fatale" (Mode par defaut)
C     2 : Passer outre toute erreur detectee, meme si elle correspond
C         a un fichier ouvert avec l'option "erreur fatale".
C         Neanmoins, le code-reponse eventuel ne sera pas zero.
C
#include "precision.h"
C
#include "facomp.h"
#include "facom1.h"
C
      INTEGER KNIVAU
C
      INTEGER IREP, INIMES, INUMER
C
      LOGICAL LLPREA
      SAVE LLPREA
C
      DATA LLPREA /.TRUE./
C
      IF (LLPREA) THEN
        CALL FARINE (2)
        LLPREA=.FALSE.
      ENDIF
C
      IF (KNIVAU.GE.0.AND.KNIVAU.LE.2) THEN
        NRFAGA=KNIVAU
        CALL LFINEG (KNIVAU)
        IREP=0
      ELSE
        IREP=-52
      ENDIF
C
      LLFATA=IREP.NE.0.AND.NRFAGA.NE.2
C
      IF (LLFATA) THEN
        INIMES=2
      ELSEIF (IREP.NE.0) THEN
        INIMES=0
      ELSEIF (NIMSGA.EQ.2) THEN
        INIMES=2
      ELSE
        RETURN
      ENDIF
C
      INUMER=JPNIIL
      CLNSPR='FANERG'
C
      IF (MAX (INIMES,NIMSGA).EQ.2) THEN
        WRITE (UNIT=CLMESS,FMT='(''KNIVAU='',I5,'', CODE INTERNE='',I4)'
     S         ) KNIVAU,IREP
      ENDIF
C
      CALL FAIPAR (INUMER,INIMES,IREP,LLFATA,CLMESS,CLNSPR,CLACTI,
     S             .FALSE.)
C
      RETURN
      END
