      SUBROUTINE LFINEG ( KNIVAU )
#include "lficomt.h"
C****
C        CE SOUS-PROGRAMME SE CHARGE DE METTRE LE NIVEAU GLOBAL D'ERREUR
C     FATALE (*NERFAG*) A LA VALEUR KNIVAU . PAR  DEFAUT, NERFAG VAUT 1.
C**
C        ARGUMENT : KNIVAU (ENTREE) ==> NIVEAU GLOBAL D'ERREUR FATALE.
C                                       VALEURS POSSIBLES
C
C     0 : RENDRE FATALE TOUTE ERREUR DETECTEE, MEME SI ELLE CORRESPOND
C         A UN FICHIER OUVERT AVEC L'OPTION "PAS D'ERREUR FATALE".
C     1 : NE REND FATALES QUE CERTAINES ERREURS "GLOBALES", C'EST-A-DIRE
C         NON RELIABLES A UN FICHIER OUVERT, ET LES ERREURS SUR LES  FI-
C         CHIERS OUVERTS AVEC L'OPTION "ERREUR FATALE" (MODE PAR DEFAUT)
C     2 : PASSER OUTRE TOUTE ERREUR DETECTEE, MEME SI ELLE CORRESPOND
C         A UN FICHIER OUVERT AVEC L'OPTION "ERREUR FATALE".
C         NEANMOINS, LE CODE-REPONSE EVENTUEL NE SERA PAS ZERO.
C
#include "lficom0.h"
#ifndef f77
#include "precision.h"
#endif
#include "lficom1.h"
C
      INTEGER KNIVAU, INIMES, IREP, INUMER
C
      LOGICAL LLPREA
      SAVE LLPREA
C
      DATA LLPREA /.TRUE./
C
      IF (LLPREA) THEN
        CALL LFIINI (2)
        LLPREA=.FALSE.
      ENDIF
C
      IF (KNIVAU.GE.0.AND.KNIVAU.LE.2) THEN
        NERFAG=KNIVAU
        IREP=0
      ELSE
        IREP=-2
      ENDIF
C
      LLFATA=IREP.NE.0.AND.NERFAG.NE.2
C
      IF (LLFATA) THEN
        INIMES=2
      ELSEIF (IREP.NE.0) THEN
        INIMES=0
      ELSEIF (NIMESG.EQ.2) THEN
        INIMES=2
      ELSE
        RETURN
      ENDIF
C
      INUMER=JPNIL
      CLNSPR='LFINEG'
C
      IF (MAX0 (INIMES,NIMESG).EQ.2) THEN
C
        IF (LFRANC) THEN
          WRITE (UNIT=CLMESS,FMT='(''KNIVAU='',I5,'', CODE INTERNE='',
     S           I4)') KNIVAU,IREP
        ELSE
          WRITE (UNIT=CLMESS,FMT='(''KNIVAU='',I5,'', INTERNAL CODE='',
     S           I4)') KNIVAU,IREP
        ENDIF
C
        IF (INIMES.NE.2) CALL LFIEMS (INUMER,NIMESG,IREP,.FALSE.,CLMESS,
     S                                CLNSPR,CLACTI)
      ENDIF
C
      CALL LFIEMS (INUMER,INIMES,IREP,LLFATA,CLMESS,CLNSPR,CLACTI)
C
      RETURN
      END
