SUBROUTINE LWVBRTL &
 & ( KIDIA , KFDIA , KLON  , KLEV  , KUAER,&
 & PGASUR, PGBSUR, PGATOP, PGBTOP,&
 & PABCU5 , PADJD5 , PADJU5,&
 & PB5    , PBINT5 , PBSUR5 , PBTOP5,&
 & PDISD5 , PDISU5 , PEMIS5 , PEMIW5,&
 & PDWFSU5, PFLUC5 ,                 &
 & PABCU  , PADJD  , PADJU  ,&
 & PB     , PBINT  , PBSUR  , PBTOP ,&
 & PDISD  , PDISU  , PEMIS  , PEMIW ,&
 & PDWFSU , PFLUC  )              

!**** *LWVBTL*   - L.W., VERTICAL INTEGRATION, EXCHANGE WITH BOUNDARIES
!                      (tangent linear)

!     PURPOSE.
!     --------
!           INTRODUCES THE EFFECTS OF THE BOUNDARIES IN THE VERTICAL
!           INTEGRATION

!**   INTERFACE.
!     ----------

!        EXPLICIT ARGUMENTS :
!        --------------------
!     ==== INPUTS ===
!  Trajectory  Perturbation  Description                         Dimension
!  PABCU5      PABCU         ABSORBER AMOUNTS               (KLON,NUA,3*KLEV+1)
!  PADJD5      PADJD         CONTRIBUTION BY ADJACENT LAYERS      (KLON,KLEV+1)
!  PADJU5      PADJU         CONTRIBUTION BY ADJACENT LAYERS      (KLON,KLEV+1)
!  PB5         PB            SPECTRAL HALF-LEVEL PLANCK 
!                            FUNCTIONS                       (KLON,NSIL,KLEV+1)
!  PBINT5      PBINT         HALF-LEVEL PLANCK FUNCTIONS          (KLON,KLEV+1)
!  PBSUR5      PBSUR         SPECTRAL SURFACE PLANCK FUNCTION     (KLON,NSIL)
!  PBTOP5      PBTOP         SPECTRAL T.O.A. PLANCK FUNCTION      (KLON,NSIL)
!  PDISD5      PDISD         CONTRIBUTION BY DISTANT LAYERS       (KLON,KLEV+1)
!  PDISU5      PDISU         CONTRIBUTION BY DISTANT LAYERS       (KLON,KLEV+1)
!  PEMIS5      PEMIS         SURFACE LW EMISSIVITY                (KLON)
!  PEMIW5      PEMIW         SURFACE LW WINDOW EMISSIVITY         (KLON)
!  PGASUR      ---           SURFACE PADE APPROXIMANTS            (KLON,NIPD,2)
!  PGBSUR      ---           SURFACE PADE APPROXIMANTS            (KLON,NIPD,2)
!  PGATOP      ---           T.O.A. PADE APPROXIMANTS             (KLON,NIPD,2)
!  PGBTOP      ---           T.O.A. PADE APPROXIMANTS             (KLON,NIPD,2)

!     ==== OUTPUTS ===
!  Trajectory  Perturbation  Description                          Dimension
!  PDWFSU5     PDWFSU        SPECTRAL DOWNWARD FLUX AT SURFACE    (KLON,NSIL)
!  PFLUC5      PFLUC         RADIATIVE FLUXES CLEAR-SKY:          (KLON,2,KLEV)
!                    1  ==>  UPWARD   FLUX TOTAL

!        IMPLICIT ARGUMENTS :   NONE
!        --------------------

!     METHOD.
!     -------

!          COMPUTES THE ENERGY EXCHANGE WITH TOP AND SURFACE OF THE
!     ATMOSPHERE AND ADDS UP ALL CONTRIBUTIONS TO GET THE CLEAR-SKY 
!     FLUXES

!     EXTERNALS.
!     ----------

!          *LWTTTL*

!     REFERENCE.
!     ----------

!        SEE RADIATION'S PART OF THE MODEL'S DOCUMENTATION AND
!        ECMWF RESEARCH DEPARTMENT DOCUMENTATION OF THE IFS

!     AUTHOR.
!     -------
!        M. Janiskova  *ECMWF*       27-Jan-2006

!     MODIFICATIONS.
!     --------------
!        M.Janiskova   23-Nov-2006 reduced version for H2O and CO2
!                                  based on lwvbtl

!-----------------------------------------------------------------------

USE PARKIND1  ,ONLY : JPIM     ,JPRB
USE YOMHOOK   ,ONLY : LHOOK,   DR_HOOK

USE YOELW    , ONLY : NSIL     ,NIPD     ,NTRA     ,NUA      ,NG1P1

IMPLICIT NONE

INTEGER(KIND=JPIM),INTENT(IN)    :: KLON 
INTEGER(KIND=JPIM),INTENT(IN)    :: KLEV 
INTEGER(KIND=JPIM),INTENT(IN)    :: KIDIA 
INTEGER(KIND=JPIM),INTENT(IN)    :: KFDIA 
INTEGER(KIND=JPIM),INTENT(IN)    :: KUAER 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGASUR(KLON,NIPD,2) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGBSUR(KLON,NIPD,2) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGATOP(KLON,NIPD,2) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGBTOP(KLON,NIPD,2) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PABCU5(KLON,NUA,3*KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PADJD5(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PADJU5(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PB5(KLON,NSIL,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PBINT5(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PBSUR5(KLON,NSIL) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PBTOP5(KLON,NSIL) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PDISD5(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PDISU5(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PEMIS5(KLON) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PEMIW5(KLON) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PDWFSU5(KLON,NSIL) 
REAL(KIND=JPRB)   ,INTENT(OUT)   :: PFLUC5(KLON,2,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PABCU(KLON,NUA,3*KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PADJD(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PADJU(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PB(KLON,NSIL,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PBINT(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PBSUR(KLON,NSIL) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PBTOP(KLON,NSIL) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PDISD(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PDISU(KLON,KLEV+1) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PEMIS(KLON) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PEMIW(KLON) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PDWFSU(KLON,NSIL) 
REAL(KIND=JPRB)   ,INTENT(OUT)   :: PFLUC(KLON,2,KLEV+1) 

!-----------------------------------------------------------------------

!*       0.1   ARGUMENTS
!              ---------

!-----------------------------------------------------------------------

!              ------------

REAL(KIND=JPRB) :: ZBSUR(KLON,NSIL), ZTT(KLON,NTRA)
REAL(KIND=JPRB) :: ZUU(KLON,NUA) , ZCNSOL(KLON)   , ZCNTOPS(KLON) 
REAL(KIND=JPRB) :: ZBSUR5(KLON,NSIL), ZTT5(KLON,NTRA)
REAL(KIND=JPRB) :: ZUU5(KLON,NUA) , ZCNSOL5(KLON) , ZCNTOPS5(KLON) 

REAL(KIND=JPRB) :: ZCNTOP1, ZCNTOP2, ZCNTOP3, ZCNTOP4, ZCNTOP5, ZCNTOP6
REAL(KIND=JPRB) :: ZCNTOP15, ZCNTOP25, ZCNTOP35
REAL(KIND=JPRB) :: ZCNTOP45, ZCNTOP55, ZCNTOP65
REAL(KIND=JPRB) :: ZXN, ZXD, ZZ
REAL(KIND=JPRB) :: ZXN5, ZXD5, ZZ5
REAL(KIND=JPRB) :: ZXDIV5

INTEGER(KIND=JPIM) :: IN, JA, JK, JL

REAL(KIND=JPRB) :: ZHOOK_HANDLE

!#include "lwtttl.intfb.h"

!-----------------------------------------------------------------------

!*         1.    INITIALIZATION
!                --------------

!*         1.2     INITIALIZE TRANSMISSION FUNCTIONS
!                  ---------------------------------

IF (LHOOK) CALL DR_HOOK('LWVBRTL',0,ZHOOK_HANDLE)

!DO JA=1,NTRA
DO JA = 1, KUAER
  DO JL=KIDIA,KFDIA
    ZTT (JL,JA) = 0.0_JPRB
    ZTT5(JL,JA) = 1.0_JPRB
  ENDDO
ENDDO

!DO JA=1,NUA
DO JA = 1, KUAER
  DO JL=KIDIA,KFDIA
    ZUU (JL,JA) = 0.0_JPRB
    ZUU5(JL,JA) = 1.0_JPRB
  ENDDO
ENDDO

!     ------------------------------------------------------------------

!*         2.      VERTICAL INTEGRATION
!                  --------------------

!*         2.3     EXCHANGE WITH TOP OF THE ATMOSPHERE
!                  -----------------------------------

DO JK = 1 , KLEV
  IN=(JK-1)*NG1P1+1

  DO JA=1,KUAER
    DO JL=KIDIA,KFDIA
      ZUU (JL,JA) = PABCU (JL,JA,IN)
      ZUU5(JL,JA) = PABCU5(JL,JA,IN)
    ENDDO
  ENDDO

  DO JA = 1 , 8
    DO JL = KIDIA,KFDIA
      ZZ5 = SQRT(ZUU5(JL,JA))
      IF (ZZ5 > 0.0_JPRB) THEN
        ZZ  = 0.5_JPRB*ZUU(JL,JA)/ZZ5
      ELSE
        ZZ  = 0.0_JPRB
      ENDIF
      ZXD  = (PGBTOP( JL,JA,2)+2.0_JPRB*ZZ5)*ZZ
      ZXD5 = PGBTOP( JL,JA,1) + ZZ5* (PGBTOP( JL,JA,2) + ZZ5 )
      ZXN  = ZZ*PGATOP( JL,JA,2)
      ZXN5 = PGATOP( JL,JA,1) + ZZ5*PGATOP( JL,JA,2)
      ZXDIV5 = 1.0_JPRB/ZXD5
      ZTT (JL,JA) = ZXN*ZXDIV5 - ZXN5*ZXDIV5*ZXDIV5*ZXD
      ZTT5(JL,JA) = ZXN5*ZXDIV5
    ENDDO
  ENDDO

  DO JL = KIDIA,KFDIA
    IF (ZTT5(JL,3) < 0.0_JPRB) THEN
      ZTT (JL,3) = 0.0_JPRB
      ZTT5(JL,3) = 0.0_JPRB
    ENDIF
    ZTT (JL, 9) = ZTT (JL, 8)
    ZTT5(JL, 9) = ZTT5(JL, 8)
  ENDDO

  DO JL = KIDIA,KFDIA
    ZCNTOP1  = PBTOP5(JL,1)*ZTT(JL,1) + ZTT5(JL,1)*PBTOP(JL,1)
    ZCNTOP15 = PBTOP5(JL,1)*ZTT5(JL,1)
    ZCNTOP2  = PBTOP5(JL,2)*ZTT5(JL,2)*ZTT(JL,7) &
       &     + PBTOP5(JL,2)*ZTT5(JL,7)*ZTT(JL,2) &
       &     + ZTT5(JL,2)*ZTT5(JL,7)*PBTOP(JL,2)
    ZCNTOP25 = PBTOP5(JL,2)*ZTT5(JL,2)*ZTT5(JL,7)
    ZCNTOP3  = PBTOP5(JL,3)*ZTT5(JL,4)*ZTT(JL,8) &
       &     + PBTOP5(JL,3)*ZTT5(JL,8)*ZTT(JL,4) &
       &     + ZTT5(JL,4)*ZTT5(JL,8)*PBTOP(JL,3)
    ZCNTOP35 = PBTOP5(JL,3)*ZTT5(JL,4)*ZTT5(JL,8)
    ZCNTOP4  = PBTOP5(JL,4)*ZTT5(JL,5)*ZTT(JL,9) &
       &     + PBTOP5(JL,4)*ZTT5(JL,9)*ZTT(JL,5) &
       &     + ZTT5(JL,5)*ZTT5(JL,9)*PBTOP(JL,4)
    ZCNTOP45 = PBTOP5(JL,4)*ZTT5(JL,5)*ZTT5(JL,9)
    ZCNTOP5  = PBTOP5(JL,5)*ZTT(JL,3) + ZTT5(JL,3)*PBTOP(JL,5)
    ZCNTOP55 = PBTOP5(JL,5)*ZTT5(JL,3)
    ZCNTOP6  = PBTOP5(JL,6)*ZTT(JL,6) + ZTT5(JL,6)*PBTOP(JL,6)
    ZCNTOP65 = PBTOP5(JL,6)*ZTT5(JL,6)
    ZCNTOPS (JL) = ZCNTOP1 +ZCNTOP2 +ZCNTOP3 +ZCNTOP4 +ZCNTOP5 +ZCNTOP6
    ZCNTOPS5(JL) = ZCNTOP15+ZCNTOP25+ZCNTOP35+ZCNTOP45+ZCNTOP55+ZCNTOP65
    PFLUC (JL,2,JK)=ZCNTOPS (JL)-PBINT (JL,JK)-PDISD (JL,JK)-PADJD (JL,JK)
    PFLUC5(JL,2,JK)=ZCNTOPS5(JL)-PBINT5(JL,JK)-PDISD5(JL,JK)-PADJD5(JL,JK)
    IF (JK == 1) THEN
      PDWFSU (JL,1) = ZCNTOP1 -PB (JL,1,JK)-PDWFSU (JL,1)
      PDWFSU5(JL,1) = ZCNTOP15-PB5(JL,1,JK)-PDWFSU5(JL,1)
      PDWFSU (JL,2) = ZCNTOP2 -PB (JL,2,JK)-PDWFSU (JL,2)
      PDWFSU5(JL,2) = ZCNTOP25-PB5(JL,2,JK)-PDWFSU5(JL,2)
      PDWFSU (JL,3) = ZCNTOP3 -PB (JL,3,JK)-PDWFSU (JL,3)
      PDWFSU5(JL,3) = ZCNTOP35-PB5(JL,3,JK)-PDWFSU5(JL,3)
      PDWFSU (JL,4) = ZCNTOP4 -PB (JL,4,JK)-PDWFSU (JL,4)
      PDWFSU5(JL,4) = ZCNTOP45-PB5(JL,4,JK)-PDWFSU5(JL,4)
      PDWFSU (JL,5) = ZCNTOP5 -PB (JL,5,JK)-PDWFSU (JL,5)
      PDWFSU5(JL,5) = ZCNTOP55-PB5(JL,5,JK)-PDWFSU5(JL,5)
      PDWFSU (JL,6) = ZCNTOP6 -PB (JL,6,JK)-PDWFSU (JL,6)
      PDWFSU5(JL,6) = ZCNTOP65-PB5(JL,6,JK)-PDWFSU5(JL,6)
    ENDIF
  ENDDO

ENDDO

JK = KLEV+1
IN=(JK-1)*NG1P1+1

DO JL = KIDIA,KFDIA
  ZCNTOPS (JL) = PBTOP (JL,1) + PBTOP (JL,2) + PBTOP (JL,3)&
   &           + PBTOP (JL,4) + PBTOP (JL,5) + PBTOP (JL,6)
  ZCNTOPS5(JL) = PBTOP5(JL,1) + PBTOP5(JL,2) + PBTOP5(JL,3)&
   &           + PBTOP5(JL,4) + PBTOP5(JL,5) + PBTOP5(JL,6) 
  PFLUC (JL,2,JK) = ZCNTOPS (JL)-PBINT (JL,JK)-PDISD (JL,JK)-PADJD (JL,JK)
  PFLUC5(JL,2,JK) = ZCNTOPS5(JL)-PBINT5(JL,JK)-PDISD5(JL,JK)-PADJD5(JL,JK)
ENDDO

!*         2.5     EXCHANGE WITH LOWER LIMIT
!                  -------------------------

JK = 1
IN=(JK-1)*NG1P1+1

DO JL = KIDIA,KFDIA
  ZBSUR (JL,1) = PBSUR5(JL,1)*PEMIS(JL)+PEMIS5(JL)*PBSUR(JL,1) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU(JL,1)+PDWFSU5(JL,1)*PEMIS(JL)
  ZBSUR5(JL,1) = PBSUR5(JL,1)*PEMIS5(JL) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU5(JL,1)
  ZBSUR (JL,2) = PBSUR5(JL,2)*PEMIS(JL)+PEMIS5(JL)*PBSUR(JL,2) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU(JL,2)+PDWFSU5(JL,2)*PEMIS(JL)
  ZBSUR5(JL,2) = PBSUR5(JL,2)*PEMIS5(JL) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU5(JL,2)
  ZBSUR (JL,3) = PBSUR5(JL,3)*PEMIW(JL)+PEMIW5(JL)*PBSUR(JL,3) &
   & -(1.0_JPRB-PEMIW5(JL))*PDWFSU(JL,3)+PDWFSU5(JL,3)*PEMIW(JL)
  ZBSUR5(JL,3) = PBSUR5(JL,3)*PEMIW5(JL) &
   & -(1.0_JPRB-PEMIW5(JL))*PDWFSU5(JL,3)
  ZBSUR (JL,4) = PBSUR5(JL,4)*PEMIW(JL)+PEMIW5(JL)*PBSUR(JL,4) &
   & -(1.0_JPRB-PEMIW5(JL))*PDWFSU(JL,4)+PDWFSU5(JL,4)*PEMIW(JL)
  ZBSUR5(JL,4) = PBSUR5(JL,4)*PEMIW5(JL) &
   & -(1.0_JPRB-PEMIW5(JL))*PDWFSU5(JL,4)
  ZBSUR (JL,5) = PBSUR5(JL,5)*PEMIS(JL)+PEMIS5(JL)*PBSUR(JL,5) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU(JL,5)+PDWFSU5(JL,5)*PEMIS(JL)
  ZBSUR5(JL,5) = PBSUR5(JL,5)*PEMIS5(JL) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU5(JL,5)  
  ZBSUR (JL,6) = PBSUR5(JL,6)*PEMIS(JL)+PEMIS5(JL)*PBSUR(JL,6) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU(JL,6)+PDWFSU5(JL,6)*PEMIS(JL)
  ZBSUR5(JL,6) = PBSUR5(JL,6)*PEMIS5(JL) &
   & -(1.0_JPRB-PEMIS5(JL))*PDWFSU5(JL,6)

  PFLUC (JL,1,JK) = ZBSUR (JL,1) + ZBSUR (JL,2) + ZBSUR (JL,3)&
   &              + ZBSUR (JL,4) + ZBSUR (JL,5) + ZBSUR (JL,6)
  PFLUC5(JL,1,JK) = ZBSUR5(JL,1) + ZBSUR5(JL,2) + ZBSUR5(JL,3)&
   &              + ZBSUR5(JL,4) + ZBSUR5(JL,5) + ZBSUR5(JL,6)  

  ZBSUR (JL,1) = ZBSUR (JL,1)-PB (JL,1,1)
  ZBSUR5(JL,1) = ZBSUR5(JL,1)-PB5(JL,1,1) 
  ZBSUR (JL,2) = ZBSUR (JL,2)-PB (JL,2,1)
  ZBSUR5(JL,2) = ZBSUR5(JL,2)-PB5(JL,2,1)
  ZBSUR (JL,3) = ZBSUR (JL,3)-PB (JL,3,1)
  ZBSUR5(JL,3) = ZBSUR5(JL,3)-PB5(JL,3,1)
  ZBSUR (JL,4) = ZBSUR (JL,4)-PB (JL,4,1)
  ZBSUR5(JL,4) = ZBSUR5(JL,4)-PB5(JL,4,1)
  ZBSUR (JL,5) = ZBSUR (JL,5)-PB (JL,5,1)
  ZBSUR5(JL,5) = ZBSUR5(JL,5)-PB5(JL,5,1)
  ZBSUR (JL,6) = ZBSUR (JL,6)-PB (JL,6,1)
  ZBSUR5(JL,6) = ZBSUR5(JL,6)-PB5(JL,6,1)
ENDDO

DO JK = 2 , KLEV+1
  IN=(JK-1)*NG1P1+1

  DO JA=1,KUAER
    DO JL=KIDIA,KFDIA
      ZUU (JL,JA) = PABCU (JL,JA,1)-PABCU (JL,JA,IN)
      ZUU5(JL,JA) = PABCU5(JL,JA,1)-PABCU5(JL,JA,IN)
    ENDDO
  ENDDO

  DO JA = 1 , 8
    DO JL = KIDIA,KFDIA
      ZZ5 = SQRT(ZUU5(JL,JA))
      IF (ZZ5 > 0.0_JPRB) THEN
        ZZ  = 0.5_JPRB*ZUU(JL,JA)/ZZ5
      ELSE
        ZZ  = 0.0_JPRB
      ENDIF
      ZXD  = (PGBSUR( JL,JA,2)+2.0_JPRB*ZZ5)*ZZ
      ZXD5 = PGBSUR( JL,JA,1) + ZZ5* (PGBSUR( JL,JA,2) + ZZ5 )
      ZXN  = ZZ*PGASUR( JL,JA,2)
      ZXN5 = PGASUR( JL,JA,1) + ZZ5*PGASUR( JL,JA,2)
      ZXDIV5 = 1.0_JPRB/ZXD5
      ZTT (JL,JA) = ZXN*ZXDIV5 - ZXN5*ZXDIV5*ZXDIV5*ZXD
      ZTT5(JL,JA) = ZXN5*ZXDIV5
    ENDDO
  ENDDO

  DO JL = KIDIA,KFDIA
    IF (ZTT5(JL,3) < 0.0_JPRB) THEN
      ZTT (JL,3) = 0.0_JPRB
      ZTT5(JL,3) = 0.0_JPRB
    ENDIF
    ZTT (JL, 9) = ZTT (JL, 8)
    ZTT5(JL, 9) = ZTT5(JL, 8)
  ENDDO

  DO JL = KIDIA,KFDIA
    ZCNSOL (JL) = ZBSUR5(JL,1)*ZTT(JL,1) + ZTT5(JL,1)*ZBSUR(JL,1) &
     & + ZBSUR5(JL,2)*ZTT5(JL,2)*ZTT(JL,7) &
     & + ZBSUR5(JL,2)*ZTT5(JL,7)*ZTT(JL,2) &
     & + ZTT5(JL,2)*ZTT5(JL,7)*ZBSUR(JL,2) &
     & + ZBSUR5(JL,3)*ZTT5(JL,4)*ZTT(JL,8) &
     & + ZBSUR5(JL,3)*ZTT5(JL,8)*ZTT(JL,4) &
     & + ZTT5(JL,4)*ZTT5(JL,8)*ZBSUR(JL,3) &
     & + ZBSUR5(JL,4)*ZTT5(JL,5)*ZTT(JL,9) &
     & + ZBSUR5(JL,4)*ZTT5(JL,9)*ZTT(JL,5) &
     & + ZTT5(JL,5)*ZTT5(JL,9)*ZBSUR(JL,4) &
     & + ZBSUR5(JL,5)*ZTT(JL,3) + ZTT5(JL,3)*ZBSUR(JL,5) &
     & + ZBSUR5(JL,6)*ZTT(JL,6) + ZTT5(JL,6)*ZBSUR(JL,6)
    ZCNSOL5(JL) = ZBSUR5(JL,1)*ZTT5(JL,1) &
     & + ZBSUR5(JL,2)*ZTT5(JL,2)*ZTT5(JL,7) &
     & + ZBSUR5(JL,3)*ZTT5(JL,4)*ZTT5(JL,8) &
     & + ZBSUR5(JL,4)*ZTT5(JL,5)*ZTT5(JL,9) &
     & + ZBSUR5(JL,5)*ZTT5(JL,3) &
     & + ZBSUR5(JL,6)*ZTT5(JL,6) 
    PFLUC (JL,1,JK) = ZCNSOL (JL)+PBINT (JL,JK)-PDISU (JL,JK)-PADJU (JL,JK)
    PFLUC5(JL,1,JK) = ZCNSOL5(JL)+PBINT5(JL,JK)-PDISU5(JL,JK)-PADJU5(JL,JK)
  ENDDO

ENDDO

!     ------------------------------------------------------------------

IF (LHOOK) CALL DR_HOOK('LWVBRTL',1,ZHOOK_HANDLE)
END SUBROUTINE LWVBRTL
