SUBROUTINE M7_EMI_SS_MON &
  &( KIDIA, KFDIA, KLON , &
  &  PCI  , PLSM , PWIND, &
  &  PFLXM7 & 
  &)

!*** * M7_EMI_SS_MON* - SOURCE TERMS FOR SEA SALT AEROSOLS A LA MONAHAN

!**   INTERFACE.
!     ----------
!          *M7_EMI_SS_MON* IS CALLED FROM *  *.

!     AUTHOR.
!     -------
!        JEAN-JACQUES MORCRETTE  *ECMWF*
!        FROM original M7 *seasalt_emissions_monahan *

!     SOURCE.
!     -------
!     H. Feichter, MPI
!     P. Stier   , MPI

!     MODIFICATIONS.
!     --------------
!        ORIGINAL : 2004-05-11

!-----------------------------------------------------------------------

USE PARKIND1  ,ONLY : JPIM     ,JPRB
USE YOMHOOK   ,ONLY : LHOOK,   DR_HOOK

USE YO_AERO_M7  ,ONLY : nm7aer, rmonss1, rmonss2
USE YO_AERO_TRAC,ONLY : idt_mssas, idt_msscs, idt_nas, idt_ncs

IMPLICIT NONE

!-----------------------------------------------------------------------

!*       0.1   ARGUMENTS
!              ---------

INTEGER(KIND=JPIM),INTENT(IN)    :: KLON 
INTEGER(KIND=JPIM),INTENT(IN)    :: KIDIA 
INTEGER(KIND=JPIM),INTENT(IN)    :: KFDIA 

REAL(KIND=JPRB)   ,INTENT(IN)    :: PCI(KLON), PLSM(KLON)
REAL(KIND=JPRB)   ,INTENT(IN)    :: PWIND(KLON) 

REAL(KIND=JPRB)   ,INTENT(INOUT) :: PFLXM7(KLON,nm7aer)


!*       0.5   LOCAL VARIABLES
!              ---------------

INTEGER(KIND=JPIM) :: JL

REAL(KIND=JPRB) :: ZSPEED, ZSSMASSA, ZSSMASSC

REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-----------------------------------------------------------------------
IF (LHOOK) CALL DR_HOOK('M7_EMI_SS_MON',0,ZHOOK_HANDLE)

ZSSMASSA= 0.37E-15_JPRB   ! mass of assumulation mode SS particle [kg]
ZSSMASSC= 0.37E-12_JPRB   ! mass of coarse mode SS particle [kg]
 
DO JL=KIDIA,KFDIA

!*       1.    EMITTED MASS-FLUX
!              -----------------
  
  ZSPEED=MIN(PWIND(JL), 20._JPRB)
  IF (PLSM(JL) == 1._JPRB) THEN
    PFLXM7(JL,idt_mssas)=rmonss1*ZSPEED**3.41_JPRB*(1._JPRB-PCI(JL))
    PFLXM7(JL,idt_msscs)=rmonss2*ZSPEED**3.41_JPRB*(1._JPRB-PCI(JL))
  ELSE
    PFLXM7(JL,idt_mssas)=0._JPRB
    PFLXM7(JL,idt_msscs)=0._JPRB
  ENDIF

!*       2.    EMITTED NUMBER-FLUX
!              -------------------

! accumulation soluble
  PFLXM7(JL,idt_nas)=PFLXM7(JL,idt_nas)+PFLXM7(JL,idt_mssas)/ zssmassa
! coarse soluble
  PFLXM7(JL,idt_ncs)=PFLXM7(JL,idt_ncs)+PFLXM7(JL,idt_msscs)/ zssmassc

ENDDO

!-----------------------------------------------------------------------
IF (LHOOK) CALL DR_HOOK('M7_EMI_SS_MON',1,ZHOOK_HANDLE)
END SUBROUTINE M7_EMI_SS_MON
