SUBROUTINE PPOBSACTL(KDLEN,KLEN,KDCOUNT,CDPAR,PINTH,KOBSTYPE,KCOUNT,&
 & PRESH,PRESF,PGEOPH,PGEOPF,&
 & PCP,PRF,PUF,PVF,PTF,PQF,&
 & PTS,PWS,PSN,PZ0,&
 & KDPP,PXPP,&
 & PRESH5,PRESF5,PGEOPH5,PGEOPF5,&
 & PCP5,PRF5,PUF5,PVF5,PTF5,PQF5,&
 & PTS5,PWS5,PVEG5,PSN5,PSLM5,PZ05,PRH2M5)  
!****-------------------------------------------------------------------
!****  PPOBSACTL : CANARI SURFACE POST-PROCESSING (TL)
!****  ---------
!****   AUTHOR :      P.MOLL 08-92, DG 05/94
!****                (Tangent linear version: F. Bouyssel 11-98)
!****-------------------------------------------------------------------
!***  PURPOSE : FIND OUT AN EQUIVALENT MODEL PARAMETER FOR A GIVEN OBSER
!***  -------

!     WHERE KDLEN   : FIRST DIMENSION (OBSERVATIONS)
!           KLEN    : ACTUAL NUMBER OF OBSERVATIONS
!           KDCOUNT : SECOND DIMENSION (Data)
!           CDPAR   : PARAMETER FOR POST-PROCESSING
!           PINTH   : INTERPOLATION HEIGHT
!           KOBSTYPE: OBS. TYPE
!           KCOUNT  : COUNTER OF DATA PER OBS
!           PRESH5  : HALF LEVEL PRESS. AT OBS. POINTS
!           PRESF5  : FULL LEVEL PRESS. AT OBS. POINTS
!           PGEOPH5 : HALF LEVEL GEOP. AT OBS. POINTS
!           PGEOPF5 : FULL LEVEL GEOP. AT OBS. POINTS
!           PCP5    : Cp
!           PRF5    : R
!           PUF5    : U VALUES (MODEL) AT OB. POINS
!           PVF5    : V VALUES (MODEL) AT OB. POINS
!           PTF5    : T VALUES (MODEL) AT OB. POINS
!           PQF5    : Q VALUES (MODEL) AT OB. POINS
!           PTS5    : SURFACE TEMPERATURE
!           PWS5    : SOIL WETNESS
!           PVEG5   : VEGETATION
!           PSN5    : SNOW DEPTH
!           PSLM5   : SEE/LAND MASK
!           PZ05    : ROUGHNESS LENGTH
!           KDPP    : Number of fields, dimension of PXPP.
!           PXPP    : POST-PROCESSED VALUES

!     PPOBSACTL CALLED FOR SYNOP AND DRIBU FROM SURFACEO

!**   METHOD : CALL TO AN APPROPRIATE POST-PROCESSING ROUTINE
!     ------
!**   EXTERNALS : ACHMTTL
!     ---------
!     MODIFIED
!     --------
!     F.Bouyssel  98-11-25 : Simplified ro run with PREINTS
!     P.Moll      99-08-03 : implementation in cy21t1  
!     P. Moll     99/10/15 : Put Apache and ACHMT in cy22 (for MF)
!     W.Sadiki    00/11/10 : modif pour appels odb
!     R. El Khatib : 01-08-07 Pruning options
!        M.Hamrud      01-Jul-2006 Revised surface fields
!     C. Payan   2008-11    : Neutral Wind
!****-------------------------------------------------------------------

USE PARKIND1  ,ONLY : JPIM     ,JPRB
USE YOMHOOK   ,ONLY : LHOOK,   DR_HOOK

USE YOMDB
USE YOMDIM   , ONLY : NFLEVG
USE YOMLUN   , ONLY : NULOUT
USE YOMCST   , ONLY : RG
USE YOMOBS   , ONLY : LSCATT_NEUTRAL
USE YOMPHY1  , ONLY : EWFC     ,GWFC
USE YOMPHY2  , ONLY : HTCLS    ,HVCLS
USE YOMPHY   , ONLY : LSOLV    ,LFGEL
USE SURFACE_FIELDS_MIX, ONLY : YSD_VVD
USE YOMCOCTP , ONLY : NSYNOP   ,NSCATT
USE GOMS_MIX     , ONLY : YGOMEC

IMPLICIT NONE

! * DUMMY:
INTEGER(KIND=JPIM),INTENT(IN)    :: KDLEN 
INTEGER(KIND=JPIM),INTENT(IN)    :: KLEN 
INTEGER(KIND=JPIM),INTENT(IN)    :: KDCOUNT
CHARACTER(LEN=3)  ,INTENT(IN)    :: CDPAR 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PINTH(KDLEN) 
INTEGER(KIND=JPIM),INTENT(IN)    :: KOBSTYPE 
INTEGER(KIND=JPIM),INTENT(IN)    :: KCOUNT(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRESH(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRESF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGEOPH(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGEOPF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PCP(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PRF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PUF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PVF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PTF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: PQF(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PTS(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PWS(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PSN(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PZ0(KDLEN) 
INTEGER(KIND=JPIM),INTENT(IN)    :: KDPP
REAL(KIND=JPRB)   ,INTENT(OUT)   :: PXPP(KDLEN,KDCOUNT,KDPP) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRESH5(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRESF5(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGEOPH5(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PGEOPF5(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PCP5(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRF5(KDLEN,NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PUF5(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PVF5(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PTF5(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PQF5(KDLEN,0:NFLEVG) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PTS5(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PWS5(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PVEG5(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PSN5(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PSLM5(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PZ05(KDLEN) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRH2M5(KDLEN,KDCOUNT) 
REAL(KIND=JPRB) :: ZDPHIT(KDLEN),                ZDPHIV(KDLEN)
REAL(KIND=JPRB) :: ZARG(KDLEN),                  ZHV5(KDLEN)
REAL(KIND=JPRB) :: ZZ0H(KDLEN),                  ZWFC(KDLEN)
REAL(KIND=JPRB) :: ZGZ0R(KDLEN),                 ZNEIJG5(KDLEN)
REAL(KIND=JPRB) :: ZNEIJV5(KDLEN)       
REAL(KIND=JPRB) :: ZNBVNO5(KDLEN,0:NFLEVG)       
REAL(KIND=JPRB) :: ZCD5(KDLEN),                  ZCDN5(KDLEN)
REAL(KIND=JPRB) :: ZCDROV5(KDLEN),               ZCH5(KDLEN)
REAL(KIND=JPRB) :: ZCHROV5(KDLEN),               ZCPS5(KDLEN)
REAL(KIND=JPRB) :: ZDQSTS5(KDLEN),               ZGWDCS5(KDLEN)
REAL(KIND=JPRB) :: ZGZ05(KDLEN),                 ZHQ5(KDLEN)
REAL(KIND=JPRB) :: ZHU5(KDLEN),                  ZNEIJ5(KDLEN)
REAL(KIND=JPRB) :: ZQCLS5(KDLEN),                ZQS5(KDLEN)
REAL(KIND=JPRB) :: ZQSATS5(KDLEN),               ZRHCLS5(KDLEN)
REAL(KIND=JPRB) :: ZRS5(KDLEN)
REAL(KIND=JPRB) :: ZTCLS5(KDLEN),                ZUCLS5(KDLEN)
REAL(KIND=JPRB) :: ZVCLS5(KDLEN),                ZVEG5(KDLEN)
REAL(KIND=JPRB) :: ZXDROV5(KDLEN),               ZXHROV5(KDLEN)
REAL(KIND=JPRB) :: ZPCLS5(KDLEN),                ZWSI5(KDLEN)
REAL(KIND=JPRB) :: ZHV(KDLEN)
REAL(KIND=JPRB) :: ZNEIJG(KDLEN),                ZNEIJV(KDLEN)       
REAL(KIND=JPRB) :: ZNBVNO(KDLEN,0:NFLEVG)       
REAL(KIND=JPRB) :: ZCD(KDLEN),                   ZCDN(KDLEN)
REAL(KIND=JPRB) :: ZCDROV(KDLEN),                ZCH(KDLEN)
REAL(KIND=JPRB) :: ZCHROV(KDLEN),                ZCPS(KDLEN)
REAL(KIND=JPRB) :: ZDQSTS(KDLEN),                ZGWDCS(KDLEN)
REAL(KIND=JPRB) :: ZGZ0(KDLEN),                  ZHQ(KDLEN)
REAL(KIND=JPRB) :: ZHU(KDLEN),                   ZNEIJ(KDLEN)
REAL(KIND=JPRB) :: ZQCLS(KDLEN),                 ZQS(KDLEN)
REAL(KIND=JPRB) :: ZQSATS(KDLEN),                ZRHCLS(KDLEN)
REAL(KIND=JPRB) :: ZRS(KDLEN),                   ZSTAB(KDLEN)
REAL(KIND=JPRB) :: ZTCLS(KDLEN),                 ZUCLS(KDLEN)
REAL(KIND=JPRB) :: ZVCLS(KDLEN),                 ZVEG(KDLEN)
REAL(KIND=JPRB) :: ZUCLN(KDLEN),                 ZVCLN(KDLEN)
REAL(KIND=JPRB) :: ZXDROV(KDLEN),                ZXHROV(KDLEN)
REAL(KIND=JPRB) :: ZPCLS(KDLEN),                 ZWSI(KDLEN)

REAL(KIND=JPRB) :: ZZARG,ZEPS

INTEGER(KIND=JPIM) :: ILEN,JROF,IPOSM,IMXCNT

LOGICAL :: LLDCLS,LLDHMT,LLDZ0H
REAL(KIND=JPRB) :: ZHOOK_HANDLE

#include "achmttl.intfb.h"

#include "openmp_obs.h"

!**---------------------------------------------------------------------
!**  1.  PREPARATION DU CALCUL DES PARAMETRES AUX HAUTEURS METEOS.
!**      --------------------------------------------------------

IF (LHOOK) CALL DR_HOOK('PPOBSACTL',0,ZHOOK_HANDLE)
ILEN=KLEN
IMXCNT = MAXVAL(KCOUNT(1:ILEN))
IF(IMXCNT == 0 .AND. LHOOK) CALL DR_HOOK('PPOBSACTL',1,ZHOOK_HANDLE)
IF(IMXCNT == 0) RETURN

!  REMPLISSAGE DES TABLEAUX LOCAUX.

ZDPHIT(1:ILEN) = RG*HTCLS
ZDPHIV(1:ILEN) = RG*HVCLS

IF(KOBSTYPE == NSYNOP)THEN
  DO JROF = 1 , ILEN
    ZDPHIV(JROF)=PINTH(JROF)
  ENDDO
ENDIF

LLDCLS=.FALSE.
LLDHMT=.TRUE.
LLDZ0H= LSOLV .AND. YSD_VVD%NUMFLDS >= 8

! Calculs preliminaires pour le schema sol-vegetation (WFC,HV)
IF ( LSOLV ) THEN
  DO JROF = 1 , ILEN
    IPOSM = ROBHDR(JROF,MDB_MAPOMM_AT_INDEX)
    ZARG(JROF) = YGOMEC(IPOSM)%ECARG
    ZHV5(JROF)  = YGOMEC(IPOSM)%ECHV
    ZHV (JROF)  = 0.0_JPRB
    IF (LLDZ0H) ZZ0H(JROF) = YGOMEC(IPOSM)%ECZ0H
    IF (LFGEL) ZWSI5(JROF) = YGOMEC(IPOSM)%ECSAB
    ZWSI(JROF) = 0.0_JPRB
    ZNEIJG(JROF) = 0.0_JPRB
    ZNEIJV(JROF) = 0.0_JPRB
    IF ( PSLM5(JROF) <= 0.5_JPRB ) THEN
      ZWFC(JROF) = 1.0_JPRB
    ELSE
      ZEPS=1.E-1_JPRB
      ZZARG = MAX(ZEPS,ZARG(JROF))
      ZWFC(JROF) = GWFC*(ZZARG**EWFC)
    ENDIF
  ENDDO
ENDIF

!**---------------------------------------------------------------------
!**  - 2 - Appel pour le calcul des parametres aux hauteurs meteo.
!**        ------------------------------------------------------

CALL ACHMTTL(1,ILEN,KDLEN,0,NFLEVG,&
 & PGEOPH5,PGEOPF5,PRESH5,PRESF5,PCP5,PQF5(1,1),PRF5,PTF5(1,1),&
 & PUF5(1,1),PVF5(1,1),PZ05,ZHV5,&
 & ZNEIJG5,ZNEIJV5,PSN5,PTS5,PWS5,ZWSI5,&
 & PGEOPH,PGEOPF,PRESH,PRESF,PCP,PQF(1,1),PRF,PTF(1,1),&
 & PUF(1,1),PVF(1,1),ZDPHIT,ZDPHIV,PZ0,ZZ0H,ZGZ0R,&
 & ZHV,PSLM5,ZNEIJG,ZNEIJV,PSN,PTS,PVEG5,ZWFC,PWS,ZWSI,&
 & LLDCLS,LLDHMT,LLDZ0H,&
 & ZNBVNO,ZCD,ZCDN,ZCDROV,ZCH,ZCHROV,ZCPS,ZDQSTS,ZGWDCS,&
 & ZGZ0,ZHQ,ZHU,ZNEIJ,ZQCLS,ZQS,ZQSATS,ZRHCLS,ZRS,&
 & ZSTAB,ZTCLS,ZUCLS,ZVCLS,ZUCLN,ZVCLN,ZPCLS,ZVEG,ZXDROV,ZXHROV,&
 & ZNBVNO5,ZCD5,ZCDN5,ZCDROV5,ZCH5,ZCHROV5,ZCPS5,ZDQSTS5,ZGWDCS5,&
 & ZGZ05,ZHQ5,ZHU5,ZNEIJ5,ZQCLS5,ZQS5,ZQSATS5,ZRHCLS5,ZRS5,&
 & ZTCLS5,ZUCLS5,ZVCLS5,ZPCLS5,ZVEG5,ZXDROV5,ZXHROV5,'ACHMTTL')  

!**---------------------------------------------------------------------
!**  - 3 - Stockage/initialisation des champs diagnostics
!**        necessaires a l'analyse.
!**        ----------------------------------------------

DO JROF = 1 , ILEN

  IF (CDPAR == 'H2') THEN
    IF ((PRH2M5(JROF,1) <= 0.0_JPRB).OR.(PRH2M5(JROF,1) >= 1.0_JPRB)) THEN
      PXPP(JROF,1,1) = 0.0_JPRB
    ELSE
      PXPP(JROF,1,1) = ZRHCLS(JROF)
    ENDIF
  ELSEIF (CDPAR == 'U10')     THEN
    IF(KOBSTYPE == NSCATT .AND. LSCATT_NEUTRAL) THEN
      PXPP(JROF,1,1) = ZUCLN(JROF)
      PXPP(JROF,1,2) = ZVCLN(JROF)
    ELSE
      PXPP(JROF,1,1) = ZUCLS(JROF)
      PXPP(JROF,1,2) = ZVCLS(JROF)
    ENDIF
  ELSEIF (CDPAR == 'T2') THEN
    PXPP(JROF,1,1) = ZTCLS(JROF)
  ELSEIF (CDPAR == 'TS') THEN
    PXPP(JROF,1,1) = PTS5(JROF)
  ELSE
    WRITE(NULOUT,'('' *** ERROR IN PPOBSACTL'')')
    WRITE(NULOUT,'('' *** REQUESTED PARAMETER='',A)') CDPAR
  ENDIF

ENDDO

!**---------------------------------------------------------------------
IF (LHOOK) CALL DR_HOOK('PPOBSACTL',1,ZHOOK_HANDLE)
END SUBROUTINE PPOBSACTL
