!OPTIONS XOPT(NOEVAL)
SUBROUTINE CPOZO ( KPROMA, KSTART , KPROF, KFLEV, PDT,&
 & PFCHOZ, POZONE1, PRDELP )  

!**** *CPOZO*  ACTION DES PROCESSUS PHOTOCHIMIQUES SUR L'OZONE
!              INTERFACE AVEC LES PARAMETRISATIONS PHYSIQUES  (IALPP)

!     But.   AJOUT DES TENDANCES DE L EFFET DIRECT DES PARAMETRISATIONS
!     ----   SUR LE RAPPORT DE MELANGE MASSIQUE D'OZONE

!**   Interface.
!     ----------
!        *CALL* *CPOZO ( KPROMA, KSTART , KPROF, KFLEV, PDT,
!    W                   PFCHOZ, POZONE1, PRDELP )

!        Arguments explicites :
!        ----------------------

!       KPROMA : DIMENSION HORIZONTALE                          (input)
!       KSTART a
!       KPROF : BORNE HORIZONTALE DES CALCULS                   (input)
!       KFLEV : DIMENSION ET BORNE VERTICALE                    (input)
!       PDT : PAS DE TEMPS EFFECTIF                             (input)
!       PFCHOZ (KPROMA,0:KFLEV) : FLUX D'OZONE
!               DUE AUX PARAMETRISATIONS                        (input)
!       PRDELP (KPROM,FLEV): 1./EPAISSEUR DES COUCHES           (input)
!       POZONE1 (KPROMA,KFLEV) : RAPPORT DE MELANGE D'OZONE     (output)

!        Arguments implicites :
!        ----------------------
!       UNITE NULOUT (/YOMLUN/)
!       CONSTANTES UNIVERSELLES, COMMON /YOMCST/
!       Appele par / Called by CPG.

!     Methode.
!     --------
!      Calcul des tendances a partir des flux.

!     Reference.
!    -----------

!     Auteur.
!    --------
!         A. Lasserre-Bigorry

!     Modifications :
!    ----------------
!         Original : 91-04-15
!        M.Hamrud      01-Oct-2003 CY28 Cleaning

!     ------------------------------------------------------------------

USE PARKIND1  ,ONLY : JPIM     ,JPRB
USE YOMHOOK   ,ONLY : LHOOK,   DR_HOOK

USE YOMCST   , ONLY : RG

IMPLICIT NONE

INTEGER(KIND=JPIM),INTENT(IN)    :: KPROMA 
INTEGER(KIND=JPIM),INTENT(IN)    :: KFLEV 
INTEGER(KIND=JPIM),INTENT(IN)    :: KSTART 
INTEGER(KIND=JPIM),INTENT(IN)    :: KPROF 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PDT 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PFCHOZ(KPROMA,0:KFLEV) 
REAL(KIND=JPRB)   ,INTENT(INOUT) :: POZONE1(KPROMA,KFLEV) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: PRDELP(KPROMA,KFLEV) 
INTEGER(KIND=JPIM) :: JLEV, JROF

REAL(KIND=JPRB) :: ZTENDOZ
REAL(KIND=JPRB) :: ZHOOK_HANDLE

!*
!     ------------------------------------------------------------------
!     1.- CALCUL DE L EFFET DIRECT
!     -----------------------------

IF (LHOOK) CALL DR_HOOK('CPOZO',0,ZHOOK_HANDLE)
DO JLEV = 1, KFLEV
  DO JROF = KSTART, KPROF
!     CALCUL DES TENDANCES
    ZTENDOZ = RG*PRDELP(JROF,JLEV)*(&
     & (PFCHOZ(JROF,JLEV-1) - PFCHOZ(JROF,JLEV))&
     & )  
    POZONE1(JROF,JLEV) = POZONE1(JROF,JLEV) + PDT*ZTENDOZ
  ENDDO
ENDDO

IF (LHOOK) CALL DR_HOOK('CPOZO',1,ZHOOK_HANDLE)
END SUBROUTINE CPOZO
