      SUBROUTINE LFIPOS ( KREP, KNUMER )
#include "lficomt.h"
C****
C        SOUS-PROGRAMME REMETTANT A LA VALEUR INITIALE LE "POINTEUR" DU
C     FICHIER, QUI SERT AUX ACCES "PSEUDO-SEQUENTIELS" SUR UNE UNITE
C     LOGIQUE OUVERTE POUR LE LOGICIEL DE FICHIERS INDEXES *LFI* .
C        APRES APPEL A CE SOUS-PROGRAMME, LE PREMIER APPEL SUIVANT A
C     *LFICAS* OU *LFILAS* D'UNE PART, OU BIEN A *LFICAP* OU *LFILAP*
C     D'AUTRE PART, CONCERNERA LE PREMIER (RESPECTIVEMENT LE DERNIER)
C     ARTICLE LOGIQUE DE DONNEES PRESENT (EN POSITION) DANS LE FICHIER,
C     SI L'ON N'APPELLE PAS *LFILEC* ENTRETEMPS.
C**
C    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
C                KNUMER (ENTREE) ==> NUMERO DE L'UNITE LOGIQUE.
C
#include "lficom0.h"
#ifndef f77
#include "precision.h"
#endif
#include "lficom1.h"
C
      INTEGER KREP, KNUMER, IREP, IRANG, INIMES
C
#include "lficom2.h"
C**
C     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
C-----------------------------------------------------------------------
C
      IREP=0
      CALL LFINUM (KNUMER,IRANG)
C
      IF (IRANG.EQ.0) THEN
        IREP=-1
        GOTO 1001
      ENDIF
C
       IF (LMULTI) CALL LFIVER (VERRUE(IRANG),'ON')
C**
C     2.  -  REINITIALISATION DU "POINTEUR" ET DES VALEURS "SUIVANTE"
C            ET "PRECEDENTE" .
C-----------------------------------------------------------------------
C
      NDERGF(IRANG)=JPNIL
      CNDERA(IRANG)=' '
      NSUIVF(IRANG)=JPNIL
      NPRECF(IRANG)=JPNIL
C**
C    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
C            VIA LE SOUS-PROGRAMME "LFIEMS" .
C-----------------------------------------------------------------------
C
 1001 CONTINUE
      KREP=IREP
      LLFATA=LLMOER (IREP,IRANG)
C
      IF (IRANG.NE.0) THEN
        NDEROP(IRANG)=14
        NDERCO(IRANG)=IREP
         IF (LMULTI) CALL LFIVER (VERRUE(IRANG),'OFF')
      ENDIF
C
      IF (LLFATA.OR.IXNIMS (IRANG).EQ.2) THEN
        INIMES=2
      ELSE
        RETURN
      ENDIF
C
      CLNSPR='LFIPOS'
      WRITE (UNIT=CLMESS,FMT='(''KREP='',I4,'', KNUMER='',I3)')
     S     KREP,KNUMER
      CALL LFIEMS (KNUMER,INIMES,IREP,LLFATA,CLMESS,CLNSPR,CLACTI)
C
      RETURN
      END
