      subroutine dd_1dv (prosca,ctonb_1dv,ctcab_1dv,n,sscale,nm,depl,
     &               aux,jmin,jmax,
     &               precos,diag,alpha,ybar,sbar)
c----
c
c     calcule le produit H.g ou
c         . H est une matrice construite par la formule de bfgs inverse
c           a nm memoires a partir de la matrice diagonale diag
c           dans un espace hilbertien dont le produit scalaire
c           est donne par prosca
c           (cf. J. Nocedal, Math. of Comp. 35/151 (1980) 773-782)
c         . g est un vecteur de dimension n (en general le gradient)
c
c     la matrice diag apparait donc comme un preconditionneur diagonal
c
c     depl = g (en entree), = H g (en sortie)
c
c     la matrice H est memorisee par les vecteurs des tableaux
c     ybar, sbar et les pointeurs jmin, jmax
c
c     alpha(nm) est une zone de travail
c
c     izs(1),rzs(1),dzs(1) sont des zones de travail pour prosca
c
c----

      implicit none
c
c         arguments
c
      logical sscale
      integer n,nm,jmin,jmax        
      real    depl(n),precos,diag(n),alpha(nm),
     &     ybar(n,n),sbar(n,n),
     &     aux(n)
      external prosca,ctonb_1dv,ctcab_1dv
c
c         variables locales
c
      integer jfin,i,j,jp
      real    r
      double precision ps
c
      jfin=jmax
      if (jfin.lt.jmin) jfin=jmax+nm
c
c         phase de descente
c
      do 100 j=jfin,jmin,-1
          jp=j
          if (jp.gt.nm) jp=jp-nm
          call prosca (n,depl,sbar(1,jp),ps)
          r=sngl(ps)
          alpha(jp)=r
          do 20 i=1,n
              depl(i)=depl(i)-r*ybar(i,jp)
20        continue
100   continue
c
c         preconditionnement
c
      if (sscale) then
          do 150 i=1,n
              depl(i)=depl(i)*precos
  150     continue
      else
          call ctonb_1dv (n,depl,aux)
          do 151 i=1,n
              aux(i)=aux(i)*diag(i)
  151     continue
          call ctcab_1dv (n,aux,depl)
      endif
c
c         remontee
c
      do 200 j=jmin,jfin
          jp=j
          if (jp.gt.nm) jp=jp-nm
          call prosca (n,depl,ybar(1,jp),ps)
          r=alpha(jp)-sngl(ps)
          do 120 i=1,n
              depl(i)=depl(i)+r*sbar(i,jp)
120       continue
200   continue
      return
      end
c
c-----------------------------------------------------------------------
c

