      SUBROUTINE LFIFMD ( KFACMD )
#include "lficomt.h"
C****
C        Ce sous-programme permet de changer le Facteur Multiplicatif
C     par Defaut du logiciel de fichiers indexes LFI.
C        Apres appel reussi a ce sous-programme, toute ouverture d'unite
C     logique LFI pour laquelle il n'y a pas de facteur multiplicatif
C     predefini (via *LFIAFM*) se fera en traitant le fichier avec une
C     longueur PHYSIQUE d'article de JPLARD*KFACMD mots.
C
C        La valeur implicite de ce Facteur Multiplicatif par Defaut est
C     definie dans *LFIINI* ( en l'occurrence, il s'agit de 1 ) .
C**
C       ARGUMENT  : KFACMD (Entree) ==> Facteur Multiplicatif par Defaut
C
#include "lficom0.h"
#ifndef f77
#include "precision.h"
#endif
#include "lficom1.h"
C
      INTEGER KFACMD, INIMES, IREP, INUMER
C
      LOGICAL LLPREA
      SAVE LLPREA
C
      DATA LLPREA/ .TRUE. /
C
      IF (LLPREA) THEN
        CALL LFIINI (2)
        LLPREA=.FALSE.
      ENDIF
C
      IF (KFACMD.LE.0) THEN
        IREP=-14
      ELSEIF (KFACMD.GT.JPFACX) THEN
        IREP=-28
      ELSE
        IREP=0
C
C          Modification, sous Verrouillage Global eventuel.
C
        IF (LMULTI) CALL LFIVER (VERGLA,'ON')
C
        MFACTU(0)=KFACMD
C
        IF (LMULTI) CALL LFIVER (VERGLA,'OFF')
      ENDIF
C
C        MESSAGERIE EVENTUELLE, AVEC ABORT SI NECESSAIRE .
C
      LLFATA=IREP.NE.0.AND.NERFAG.NE.2
C
      IF (LLFATA) THEN
        INIMES=2
      ELSEIF (IREP.NE.0) THEN
        INIMES=0
      ELSEIF (NIMESG.EQ.0) THEN
        RETURN
      ELSE
        INIMES=NIMESG
      ENDIF
C
      CLNSPR='LFIFMD'
      INUMER=JPNIL
C
      IF (INIMES.EQ.2) THEN
C
        IF (LFRANC) THEN
          WRITE (UNIT=CLMESS,FMT='(''KFACMD='',I5,'', CODE INTERNE='',
     S           I4)') KFACMD,IREP
        ELSE
          WRITE (UNIT=CLMESS,FMT='(''KFACMD='',I5,'', INTERNAL CODE='',
     S           I4)') KFACMD,IREP
        ENDIF
C
        CALL LFIEMS (INUMER,INIMES,IREP,LLFATA,CLMESS,CLNSPR,CLACTI)
      ENDIF
C
      IF (INIMES.GE.1) THEN
C
        IF (LFRANC) THEN
          WRITE (UNIT=CLMESS,FMT=
     S         '(''Reglage du Facteur Multiplicatif par Defaut a'',I3)')
     S         KFACMD
        ELSE
          WRITE (UNIT=CLMESS,FMT=
     S         '(''Default Multiply Factor set to'',I3)')
     S         KFACMD
        ENDIF
C
      ENDIF
C
      CALL LFIEMS (INUMER,INIMES,IREP,LLFATA,CLMESS,CLNSPR,CLACTI)
C
      RETURN
      END
